Ondrej Sevecek's Blog

Vypsat seznam všech protokolů z TMG (Threat Management Gateway 2010), nebo ISA Serveru není těžké. Stačí si je vyexportovat pomocí GUI do .XML souboru. V tom XML souboru se ale špatně hledá a není to úplně přehledné. Navíc by si člověk chtěl třeba výpis nějak upravit apod.

Tak tu je VBS skript (vbscript), který vypíše všechny protokolové definice z firewallu. Kdo chce, upraví si podle potřeby, například na vyhledání určitého čísla portu:

Set root = CreateObject("FPC.Root") 
Set protocolDefs = root.GetContainingArray.RuleElements.ProtocolDefinitions 

for each protDef in protocolDefs 

  WSCript.Echo protDef.Name 

  for each primCon in protDef.PrimaryConnections 

    proto = primCon.Protocol 

    select case proto 
      case 1: protoStr = "ICMP" 
      case 2: protoStr = "IGMP" 
      case 3: protoStr = "GGP" 
      case 4: protoStr = "IP" 
      case 5: protoStr = "ST" 
      case 6: protoStr = "TCP" 
      case 17: protoStr = "UDP" 
      case 58: protoStr = "ICMPv6" 
      case 50: protoStr = "ESP" 
      case 51: protoStr = "AH" 
      case 41: protoStr = "IPv6 over IPv4 Tunnel" 
      case else: 
                 protoStr = "unknown (" & proto & ")" 
                 InputBox "stiskni" 
    end select 

    if proto = 6 Or proto = 17 then 

      if primCon.PortLow <> primCon.PortHigh then 

        WScript.Echo vbTab & protoStr & _ 
                     " : " & primCon.PortLow & " - " & primCon.PortHigh 

      else 

        WScript.Echo vbTab & protoStr & _ 
                     ": " & primCon.PortLow 

      end if 

    elseif proto = 1 Or proto = 58 then 
       
      WScript.Echo vbTab & protoStr & _ 
                   " : Code " & primCon.ICMPCode & ", Type " & primCon.ICMPType 

    else 

      WScript.Echo vbTab & protoStr 

    end if 

  next 

next